魔兽世界10.0DH宏命令大全

魔兽世界10.0快上线了，在10.0版本职业天赋大改版，很多功能技能都需要玩家点天赋学习，导致一些宏失效了，下面就给大家带来魔兽世界10.0DH宏命令大全，大家可以来参考一下。

魔兽世界10.0DH宏命令大全

1.复杂的上马宏

/cancelaura 幽灵视觉

/use [nocombat]秘魔刃豹

/dismount [mounted]

/cast 滑翔

/cast [mod]疾影

/stopmacro [nocombat][channeling]

/target [@mouseover,harm]

/cast [@mouseover,harm] []邪能之刃

/stopmacro [@mouseover,noharm] [mod]

/targetlasttarget

/focus target

/targetlasttarget

功能解释：

这个宏我编在鼠标侧键，功能有点多

1.不在战斗则召唤坐骑，在战斗则使用[邪能之刃]

2.如果战斗中鼠标指向了一个敌对目标，则切换该目标施放[邪能之刃]，并且把当前的目标设置为焦点

3.如果按下alt/shift/ctrl，则施放[疾影](不管在不在战斗状态)

4.如果在天上就滑翔

5.取消[幽灵视觉]回到正常移速

运用场景：

你正开心的打着怪，突然来了优先级更高的add，或者敌对玩家，你只需按一个键，就可以跳到这个目标身边，并同时把当前正在打的目标设置成焦点。

然后就是上/下马，空中飞一飞， 开个闪避 之类的

使用该宏需要注意的问题：

1.快捷键不要冲突，假设这个宏的快捷键是E,那[alt+E]，[shift+E]，[ctrl+E]别设置成快捷键，不然会使施放[疾影]的语句失效

2.注意与鼠标指向目标的距离，如果超出距离，则无法使用[邪能之刃]

3.注意GCD，在技能转GCD的时候忍着别按

下面是逐行注解，抛砖引玉，大家可以按自己习惯DIY

/cancelaura 幽灵视觉 ——如果有幽灵视觉则取消，吐槽一下，幽灵视觉的移动速度太慢了

/use [nocombat]秘魔刃豹 ——如果不在战斗，使用坐骑，我氪了基佬紫的这个豹， 感觉还挺好看的 ，这里换坐骑可以先打开坐骑的界面，在/use 语句后面按住shift点击你想用的坐骑

/dismount [mounted] ——如果在马上，就下马

/cast 滑翔 ——如果在天上，就[滑翔]，这里的滑翔按第二下会取消，手速太快的可以写成 /cast !滑翔，这样滑翔就不会取消了

/cast [mod]疾影 ——如果同时按下alt/shift/ctrl，释放[疾影]

/stopmacro [nocombat][channeling] ——如果不在战斗状态，没使用任何通道类技能(如眼棱、弹幕)，则宏在这里停止，这句的目的是优先把眼棱弹幕打完再施放其他技能

/target [@mouseover,harm] ——把鼠标指向(并且可以攻击的)目标设置为目标

/cast [@mouseover,harm] []邪能之刃 ——向鼠标指向的(并且可以攻击的)目标释放[邪能之刃]，如果鼠标没有指向任何目标，则对当前目标使用[邪能之刃]

/stopmacro [@mouseover,noexists] [mod] ——如果鼠标没有指向任何目标，或者在alt/shift/ctrl按下时，则宏在这里停止，这句的目的是为了在对当前目标进行[邪能之刃]时，不改变当前焦点(如果有的话)

/targetlasttarget ——选择上一个目标(如果宏运行到这儿了，这里的lasttarget指的是add前你正在打的那个目标，你现在的目标已经是add了，我们选择add前这个目标)

/focus target ——并把这个目标设置为焦点

/targetlasttarget ——选择上一个目标(上一个目标指的是add，宏到这里完成了把add前的目标设置为焦点，并把add设置成当前目标)

2.禁锢宏

#showtooltips 禁锢

/cast [@mouseover,exists] [mod,@focus,exists]禁锢

/focus [@mouseover,exists]

/stopmacro [@mouseover,noexists] [mod]

/cast 禁锢

/focus target

/cancelaura 献祭光环

/stopattack

功能解释：

1.如果鼠标指向的目标是敌对的就[禁锢]它，并把它设置成焦点

2.如果鼠标没指向任何目标就[禁锢]当前的目标

2.如果按了alt/shift/ctrl，就禁锢焦点

3.如果是对当前目标使用禁锢，就取消献祭光环，停止自动攻击，免得没有天赋支持的时候烧醒了

运用场景：

满足任何需要[禁锢]技能的情况

使用该宏需要注意的问题：

1.快捷键不要冲突，假设这个宏的快捷键是E,那[alt+E]，[shift+E]，[ctrl+E]不要设置成快捷键，不然会使对焦点施放[禁锢]的语句失效

2.注意与鼠标指向目标的距离，如果超出距离，则无法使用[禁锢]

逐行注解

/cast [@mouseover,exists] [mod,@foucs,exists]禁锢 ——对鼠标指向的目标施放[禁锢]，如果按了alt/shift/ctrl，就禁锢焦点

/focus [@mouseover,exists] ——把鼠标指向的目标设置成焦点

/stopmacro [@mouseover,exists,harm][mod] ——如果鼠标指向有可以攻击的目标 或者 按了alt/shift/ctrl 宏在这里结束，这样就不会在[禁锢]其他(远距离)目标时停止攻击当前的目标或取消献祭。

/cast 禁锢 ——对当前目标施放禁锢

/focus target ——把当前目标设置成焦点

/cancelaura 献祭光环 ——取消献祭光环

/stopattack ——停止攻击

3.鬼畜赞怒宏

#showtooltip

/cancelaura 虚空行走

/f

/stopmacro [help][channeling]

/cast [harm]恶魔之咬

/cast [harm]裂魂

/cast !滑翔

/cast [combat,noexists][mod]幽灵视觉

/stopmacro [harm]

/targetlasttarget

功能解释：

1.打恶魔之咬，如果目标是友方就跟随

2.取消虚空行走，继续开撸

3.战斗时，如果突然没了目标就开[幽灵视觉]选择丢失的目标 ——这行对盗贼、法师很不友好

4.被boss击飞时，开滑翔，不会飞太远

逐行注解

#showtooltip

/cancelaura 虚空行走 ——取消虚空行走

/f ——跟随目标

/stopmacro [help][channeling] ——如果当前目标为友方 或者 在施放通道魔法则宏在这停止

/cast [harm]恶魔之咬

/cast [harm]裂魂

/cast !滑翔 ——不在地上就滑翔

/cast [combat,noexists][mod]幽灵视觉 ——战斗中没有目标或者按下alt/shift/ctrl，就施放[幽灵视觉]

/stopmacro [harm] ——如果当前有可攻击的目标 宏在这停止

/targetlasttarget ——(如果战斗中没有目标 就)选择上一个目标

4.焦点与目标互换宏

/cleartarget [@target,dead]

/clearfocus [@focus,dead]

/target [@focus,harm]

/cast 邪能之刃

/targetlasttarget

/focus target

/targetlasttarget

功能解释：

1.把当前目标设置为焦点

2.把当前焦点设置为目标

运用场景：

转火!转火!转火!

这里顺带说一下，因为DH的位移技能只有邪能之刃是目标指向的，才15码而且有GCD，所以效果并没有[暗影步][冲锋]好，如果你有战士或者DZ，本宏实用性会大大提高，值得拥有!

逐行注解

/cleartarget [@target,dead] ——如果目标死亡就清除目标(相当于点地板)

/clearfocus [@focus,dead] ——如果焦点死亡就清除焦点

/target [@focus,harm] ——把焦点设置为目标(如果有焦点而且焦点是敌对目标)

/cast 邪能之刃

/targetlasttarget ——选择上一个目标(这里指的是焦点变为目标前的那个目标)

/focus target ——把这个目标设置为焦点

/targetlasttarget ——选择上一个目标(也就是按下宏键前的焦点目标)

另外附上一个暗影步版加了鼠标指向的一键转火宏

比单纯的鼠标指向宏方便，因为目标跟着一起切换了，真正做到了一键

而且转火前的目标或成为新的焦点

/clearfocus [@focus,dead]

/cast [nostealth]!潜行

/target [@mouseover,harm]

/target [mod,@focus,harm]

/cast 暗影步

/stopmacro [@mouseover,noexists] [nomod]

/targetlasttarget

/focus target

/targetlasttarget

5.投掷宏

#showtooltips 投掷利刃

/clearfocus [@focus,dead]

/cast [@mouseover,harm] [mod,@focus,exists][]投掷利刃

/stopmacro [@focus,exists,harm]

/focus [@mouseover,harm]

功能解释：

与禁锢宏一样的原理

1.向鼠标指的目标[投掷利刃]，如果此时你没有焦点，就把它设置为焦点

2.按下alt/shift/ctrl时就对焦点目标投掷利刃

3.鼠标没目标就对当前目标投掷利刃

使用场景：

在不影响当前作战目标的情况下，向add[投掷利刃]并设置新焦点，为转火做前戏或者就是单纯想关爱一下焦点

逐行注解

#showtooltips 投掷利刃

/clearfocus [@focus,dead] ——如果焦点目标已经死亡就取消焦点

/cast [@mouseover,harm] [mod,@focus,exists][]投掷利刃 ——向鼠标指的目标[投掷利刃]，如果按下alt/shift/ctrl，就对焦点目标[投掷利刃]，如果鼠标没目标，也没按下alt/shift/ctrl，就对当前目标[投掷利刃]

/stopmacro [@focus,exists,harm] ——如果已经有焦点了并且焦点是可以攻击的对象 宏在这里停止，这是为了保证已有焦点不会被更换

/focus [@mouseover,harm] ——把鼠标指向的目标设置为焦点

6.其他

对DH来讲比较实用的宏语句

/stopmacro [channeling] ——如果当前在施放通道魔法则宏在这里停止，这一条可以加在所有的鬼畜宏的第一句，来保护[眼棱]和[弹幕]的完整施放

/cancelaura 虚空行走 ——取消虚空行走(被奶回来了，别傻站着)

/cancelaura 幽灵视觉 ——取消幽灵视觉(幽灵视觉的减速很讨厌)

/cancelaura 献祭光环 ——取消献祭光环(不打破别人控制技能 不额外add小怪)

/cancelaura 恶魔践踏 ——取消恶魔践踏(撞倒就好了，不用一直跑)

/cast [@cursor] xxx技能 如[恶魔变形][暴风雪][扰乱] ——在鼠标指针的位置一键施放无目标类技能，个人很不建议把[恶魔变形]做成一键施放，非常珍贵的位移加控制，需要保证精度，尤其在水里的时候，Z轴的判定非常奇葩

/cast [@player] xxx技能 如[烈焰咒符] ——以自己为中心一键施放无目标类技能

/cast !恶魔变形 ——在技能前加一个"!"即使你鬼畜按很多下，也不会让施法圈消失

DH没有GCD的技能(可以加在任何宏里又不影响宏使用)

通用：[滑翔][折磨][瓦解][角斗士勋章][潜行(暗夜精灵)]

浩劫：[疾影]

复仇：[恶魔尖刺][地狱火撞击](地狱火撞击只跟地狱火撞击有GCD)

人人都有两个目标，当前目标和焦点目标，你可以借助WA插件随时掌控两个目标的一切行为和动向，并在PVP的时候做出最佳决策。

强烈建议用WA加入焦点距离的判定提示，≤15码、≤20码、≤30码、无限远 以便随时的控制或转火。

相关链接：魔兽世界10.0全职业宏命令分享